TKSoft-Online

Public Function SetProp(strEigenschaftenname As String, varEigenschaftentyp As Variant, _
                        varEigenschaftenwert As Variant) As Integer
'*******************************************
'Name:      SetProp (Function)
'Purpose:   Setzen von Datenbank Einstellungen
'Author:    Thomas Keßler
'Date:      Dezember 15, 2002, 11:04:37
'Inputs:    strEigenschaftenname= Die Eigenschaft die gesetzt werden soll
'           varEigenschaftentyp = Typ der Eigenschaft, 
'           varEigenschaftenwert = Wert der Eigenschaft
'Output:    gibt True zurück wenn Eigenschaft eingestellt wurde, sonst False
'*******************************************
    Dim db As DAO.Database
    Dim prp As Property
    Const conPropNotFoundError = 3270

    Set db = CurrentDb
    On Error GoTo Ändern_Fehler
    db.Properties(strEigenschaftenname) = varEigenschaftenwert
    SetProp = True

Ändern_Ende:
    Exit Function

Ändern_Fehler:

    If Err = conPropNotFoundError Then  ' Eigenschaft nicht gefunden.
        Set prp = db.CreateProperty(strEigenschaftenname, _
            varEigenschaftentyp, varEigenschaftenwert)
        db.Properties.Append prp
        Resume Next
    Else
        ' Unbekannter Fehler.
        SetProp = False
        Resume Ändern_Ende
    End If
End Function